AquilaX's development blog » Processing

Chasing balls with faiding tails

AquilaX — Mon, 03 Mar 2008 10:56:51 +0000

Another very simple Processing script. Nothing fancy just three points with circle orbits and blur on every step to ensure the fading of the "tails" but still looks nice.

 
int R = 20;  //radius
int speed = 2;  // speed
 
int t = 0;
float x;
float y;
int offx = 0;
int offy = 0;
 
void setup(){
  size(80,80);
  offx = width/2;
  offy = height/2;
  background(0);
  strokeWeight(7);
}
 
void draw(){
  filter(BLUR,1);
  stroke(#FF0000);
  x = sin(radians(t))*R+offx;
  y = cos(radians(t))*R+offy;
  point (x,y);
  stroke(#00FF00);
  x = sin(radians(t+120))*R+offx;
  y = cos(radians(t+120))*R+offy;
  point (x,y);
  stroke(#0000FF);
  x = sin(radians(t+240))*R+offx;
  y = cos(radians(t+240))*R+offy;
  point (x,y);
  t += speed;
}

Spirograph with Processing

AquilaX — Mon, 03 Mar 2008 10:07:57 +0000

I continue my tests with Processing. Today's project is simple Spirograph. The formulas are taken from here.

 
int R = 130;         //Outer radius
int r = 15;          //Iner radius
int O = 7;           //Offset
float swidth = 0.2;  // Stroke width
int iter = 500;      // Numer of iterations
 
float x;
float y;
float ox = 0;
float oy = 0;
int offx;
int offy;
int t = 0;
 
void setup(){
  size(400,400);
  offx = width/2;
  offy = height/2;
  colorMode(HSB, iter);
  strokeWeight(swidth);
  background(0);
  smooth();
}
 
void draw(){
  if (t <= iter){
    x = (R+r)*cos(t) - (r+O)*cos(((R+r)/r)*t)+offx;
    y = (R+r)*sin(t) - (r+O)*sin(((R+r)/r)*t)+offy;
    stroke(t, iter/1.5, iter);
    //point (x, y);  //<- points
    if (ox != 0 && oy != 0){
      line (ox, oy, x, y);  //<-lines
    }
    ox = x;
    oy = y;
    t++;
  }
}

Simple terrain generator in Processing

AquilaX — Sun, 02 Mar 2008 09:49:39 +0000

Here is simple processing script for generating random terrains using Perlin noise. The good thing is that Processing has integrated noise() function and all you have to do is call it with the coordinates as parameters. Then assign the colors depending on the "height" of the point and add some randomness to the snow to make it look more dispersed.

 
float noiseScale=0.02;
int tsize = 250;
 
void setup() {
  size(640, 480, P3D);
  background(0);
  rotateX(radians(45));
 
  beginShape(POINTS);
  for(int x=0; x < tsize; x++) {
    for(int y=0; y < tsize; y++){
      float noiseVal = noise(x*noiseScale, y*noiseScale);
      int t = int(noiseVal*255);
      stroke(165, 80, 10);
      if (t >180 ){
        stroke(0, 0, t);
      }
      // add some randomness to the snow to make it more realistic
      if (t <60 +random(20)){
        stroke(255, 255, 255);
      }
      vertex(width/2+x-tsize/2, height/2+y-tsize/2, -noiseVal*60);
    }
  }
  endShape();
}
 
void draw(){
}